Skip to content
Hyle Astro

Your first simulation

Open Studio. A new project starts with empty main.hyle and initial.hyleworld files, and no account is needed to edit or run it. Put this complete program in main.hyle:

main.hyle
property Thermal {
    temperature: Float<1.0> [0.0 1.0];
}


model Ember : Thermal;


world {
    dimensions 3;
    cell Cube;
}


behavior Cool for Thermal {
    update {
        set self.temperature = clamp(self.temperature - 0.01, 0.0, 1.0);
    }
}


phase cooling {
    run Cool on Ember;
}


visual HeatColor for Thermal {
    color { rgba(self.temperature, 0.15, 0.05, 1.0) }
}


visualize Ember with HeatColor;

Select initial.hyleworld in the file list and give the program one starting cell:

initial.hyleworld
use models {Ember};
place Ember at [0, 0, 0];
  1. Choose Compile. Studio builds the starting cell from initial.hyleworld.
  2. Choose Select and inspect the cell. Its temperature starts at 1.0.
  3. Choose Step. Temperature decreases by 0.01, and its red color darkens. Run repeats steps; Pause stops playback. CPU-64 is the default solver.
  4. Scrub the Timeline to compare recorded states. Return to the latest frame to continue stepping or painting.
  5. Sign in and Save to keep the source and starting-world recipe as a private project. Without an account, File → Download project keeps a local package.

Saving the project keeps the recipe, not the latest simulated state. To make the visible cell state a new starting point, use Project settings → Fork from this state while signed in. The new private draft opens in another tab with that state written as captured.hyleworld.

Brush edits also change only the live scene. Use a fork to preserve them as a new starting world, or download the timeline bake to keep the recorded states. Guest work is temporary; download what you need before leaving.

Hyle Astro